*compar.scs

simulator lang=spectre

*control statements
mytran tran start=0.1ns stop=100ns
operpt info what=oppoint where=screen
save outplus outminus inplus inminus strobe strobeB
save Mn1:currents Mp1:currents

*circuit parameters
parameters wn=0.6u wp=2.4u
parameters len=0.36u
parameters pwr=2.5 gnd=0
parameters t1=10n tr=0.5n

include "./d25.m"

*voltage sources
Vdd (vdd 0) vsource dc=pwr
Vss (vss 0) vsource dc=0

Vinplus  (inplus  0) vsource type=pwl wave=[0 2V  44ns 2V 45ns 0.5V]
Vinminus (inminus 0) vsource dc=1.65

Vstrobe  (strobe  0) vsource type=pwl wave=[0      0	(t1-tr) 0 \
					    t1     pwr  (2*t1-tr) pwr\
					    (2*t1) 0]  pwlperiod=(2*t1+2*tr)
				    
VstrobeB (strobeB 0) vsource type=pwl wave=[0      pwr  (t1-tr) pwr \
					    t1     0    (2*t1-tr) 0 \
					    (2*t1) pwr] pwlperiod=(2*t1+2*tr)


*Circuit elements
Cload1 (outplus  0) capacitor c=0.2p
Cload2 (outminus 0) capacitor c=0.2p

Mn1 1		 strobe 	vss 	vss d25N l=len w=wn
Mn2 outplus	 outminus 	1 	vss d25N l=len w=wn
Mn3 outminus	 outplus 	1 	vss d25N l=len w=wn

Mn4 inminus strobeB outminus 		vss d25N l=len w=wn
Mn5 inplus  strobeB outplus  		vss d25N l=len w=wn

Mp1 2 		strobeB 	vdd 	vdd d25P l=len w=wp
Mp2 outplus 	outminus 	2 	vdd d25P l=len w=wp
Mp3 outminus 	outplus 	2 	vdd d25P l=len w=wp